SPARQL Endpoint

The public SPARQL endpoint of the Data Set Knowledge Graph is provided at

http://dskg.org/sparql

Example SPARQL queries:

  • The ten data sets from the application area Computer Science with the most linked papers (descending listed):
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>

SELECT ?dataset ?datasetTitle (COUNT(DISTINCT ?isReferencedBy) as ?NumberReferences)
WHERE { 
?dataset rdf:type dcat:Dataset .
?dataset dct:title ?datasetTitle .
?dataset dct:isReferencedBy ?isReferencedBy .
?dataset dcat:theme <http://ma-graph.org/entity/41008148> .  
} 
GROUP BY ?dataset ?datasetTitle
ORDER BY DESC(?NumberReferences)
LIMIT 10
  • The ten most influential authors in the field of biology and — if available — their ORCID ID:
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX adms: <https://www.w3.org/ns/adms#>

SELECT ?authorName ?orcid (COUNT(DISTINCT ?isReferencedBy) as ?NumberReferences)
WHERE { 
?dataset rdf:type dcat:Dataset .
?dataset dct:isReferencedBy ?isReferencedBy .
?dataset dct:creator ?author .
?dataset dcat:theme <http://ma-graph.org/entity/86803240> .
?author rdf:type foaf:Person .
?author foaf:name ?authorName .
OPTIONAL { ?author adms:identifier ?orcid }
} 
GROUP BY ?authorName ?orcid
ORDER BY DESC (?NumberReferences)
LIMIT 10
  • All datasets from the author with the ORCID ID 0000-0002-8656-3431:
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX adms: <https://www.w3.org/ns/adms#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

SELECT ?authorName (GROUP_CONCAT(?datasetTitle; SEPARATOR=", ") as ?datasetTitle) (GROUP_CONCAT(?dataset; SEPARATOR=", ") as ?dataset)    
WHERE { 
?dataset rdf:type dcat:Dataset .
?dataset dct:title ?datasetTitle .
?dataset dct:creator ?author .
?author rdf:type foaf:Person .
?author  foaf:name  ?authorName .
?author  adms:identifier  <https://orcid.org/0000-0002-8656-3431> .    
}
  • The 100 papers to which the most datasets are linked:
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>

SELECT ?isReferencedBy (COUNT(DISTINCT ?dataset)as ?NumberDatasets)
WHERE { 
?dataset rdf:type  dcat:Dataset .
?dataset dct:isReferencedBy ?isReferencedBy .
} 
GROUP BY ?isReferencedBy 
ORDER BY DESC(?NumberDatasets)
LIMIT 100